Método Activate

Activa una sección específica del cuaderno.

Sintaxis

expresión.Activate

expresión   Requerida. Una expresión que devuelve un objeto Section.

Comentarios

Puede seleccionar varias secciones a la vez, pero sólo una de ellas puede estar activa. Si activa una sección oculta, se vuelve visible.

Utilice la propiedad SelectedSectionNames para devolver o configurar la matriz de los nombres de secciones seleccionados.


Ejemplo del método Activate

Este ejemplo crea un nuevo cuaderno, agrega un libro de Microsoft Excel y un documento de Word y, a continuación, activa la primera sección del cuaderno.

Set miCuaderno = CreateObject("Cuaderno1.Binder")

miCuaderno.Visible = True

miCuaderno.Sections.Add Type:="Excel.Sheet"

miCuaderno.Sections.Add Type:="Word.Document"

miCuaderno.Sections(1).Activate


Método Add

Crea una nueva sección en el cuaderno especificado y devuelve un objeto Section que representa la nueva sección. Puede agregar una sección creando un nuevo objeto o insertando una sección basada en un archivo existente.

Sintaxis

expresión.Add(Type, FileName, Before, After)

expresión   Requerida. Una expresión que devuelve un objeto Sections.

Type   Variant opcional. Tipo de sección que se creará. Puede ser una de las siguientes clases: Excel.Chart, Excel.Sheet, Word.Document, PowerPoint.Show o PowerPoint.Slide. Si se omite este argumento, se requiere FileName.

FileName   Variant opcional. Ruta y nombre completos del archivo en que se basará la sección que desee agregar. Si se omite este argumento, se requiere Type.

Before   Variant opcional. Sección delante de la cual se agregará la nueva sección. No puede especificar Before si ha especificado After.

After   Variant opcional. Sección detrás de la cual se agregará la nueva sección. No puede especificar After si ha especificado Before.

Comentarios

Debe especificar Type o FileName. No es necesario que el nombre especificado en Type incluya el número de versión especificado en el valor devuelto por la propiedad Type.

Si omite tanto Before como After, la sección se agregará después de la última sección del cuaderno.


Ejemplo del método Add

Este ejemplo agrega un documento de Word a Cuaderno1.obd y nombra el documento resultante como "Totales".

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

Set nuevaSección = mybinder.Sections _

    .Add(Type:="Word.Document", Before:=1)

nuevaSección.Name = "Totales"


Método Copy

Copia la sección especificada en otra ubicación del cuaderno y devuelve la copia como un objeto Section. Automáticamente se asignará a la nueva copia el nombre de la sección original con un número entre paréntesis; la sección original no se moverá ni alterará.

Sintaxis

expresión.Copy(Before, After)

expresión   Requerida. Una expresión que devuelve un objeto Section.

Before   Variant opcional. Nombre o número de la sección antes de la cual se copiará el objeto. No puede especificar Before si ha especificado After.

After   Variant opcional. Nombre o número de la sección después de la cual se copiará el objeto. No puede especificar After si ha especificado Before.


Ejemplo del método Copy

Este ejemplo determina si la segunda sección de Cuaderno1.obd es una hoja de cálculo de Microsoft Excel. Si es así, se copiará después de la sección nombrada "Totales".

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

miCuaderno.Sections(2).Activate

With miCuaderno.ActiveSection

If .Type = "Excel.Sheet.8" Then

    .Copy After:="Totales"

End If

End With


Propiedad Count

Devuelve el número de elementos del conjunto Sections. Long de sólo lectura.

Comentarios

En el recuento se incluyen todas las secciones, visibles u ocultas.


Ejemplo de la propiedad Count

Este ejemplo muestra el número de secciones de Cuaderno1.obd.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

MsgBox "Hay " & miCuaderno.Sections.Count & _

    " secciones en el cuaderno: " & miCuaderno.Name


Método Delete

Elimina el objeto Section especificado.

Sintaxis

expresión.Delete

expresión   Requerida. Una expresión que devuelve un objeto Section.


Ejemplo del método Delete

Este ejemplo elimina la sección denominada "Sumas" de Cuaderno1.obd. El ejemplo hace referencia a la sección por su nombre, pero también puede referirse a la sección por su número. Puede eliminarse permanentemente la sección sólo después de haber guardado el cuaderno.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno

   .Sections("Sumas").Delete

   .Save

End With


Propiedad Index

Devuelve el número de índice del objeto Section dentro del conjunto Sections. Long de sólo lectura.

Comentarios

En el recuento del índice se incluyen todas las secciones, visibles u ocultas.

Para cambiar el orden de las secciones, utilice el método Move.


Ejemplo de la propiedad Index

Este ejemplo determina si la sección activa es la primera sección de Cuaderno1.obd. Si es así, el ejemplo mueve la primera sección y la ubica después de la tercera sección.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

miCuaderno.Visible = True

If miCuaderno.ActiveSection.Index = 1 Then

miCuaderno.ActiveSection.Move after:=3

End If


Propiedad Item

Devuelve un objeto Section del conjunto Sections. Es de sólo lectura.

Sintaxis

expresión.Item(Index)

expresión   Requerida. Una expresión que devuelve un objeto Sections.

Index   Variant requerida. Nombre o número de la sección.

Comentarios

La propiedad Item es la propiedad predeterminada del conjunto Sections. Puede utilizar Sections(index), donde index representa el nombre o número de índice de la sección, para devolver un objeto Section. El número de índice representa el orden en que aparece la sección en la lista, en el panel del Cuaderno. Sections(1) es el primer documento y Sections(Sections.Count) es el último documento.


Ejemplo de la propiedad Item

Este ejemplo muestra el nombre de la tercera sección de Cuaderno1.obd.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

nombreSección = miCuaderno.Sections.Item(3).Name

Set miCuaderno = Nothing

MsgBox nombreSección


Propiedad LeftPane

True si el panel izquierdo de la ventana del Cuaderno está visible. El panel izquierdo, también llamado panel del Cuaderno, incluye los iconos de todas las secciones del cuaderno. Boolean de Lectura/Escritura.

Comentarios

Si esta propiedad es False, el panel del Cuaderno no está visible, pero dispone de un botón que puede utilizar para mostrarlo.


Ejemplo de la propiedad LeftPane

Este ejemplo utiliza el método Open para abrir el cuaderno Cuaderno2.obd. El ejemplo agrega un nuevo documento de Word al cuaderno y muestra el panel del Cuaderno.

Set miCuaderno = CreateObject("Cuaderno1.Binder")

With miCuaderno

    .Open "Cuaderno2.obd"

    .Visible = True

    .Sections.Add Type:="Word.Document"

    .LeftPane = True

End With


Método Move

Mueve la sección especificada a otra ubicación del cuaderno.

Sintaxis

expresión.Move(Before, After)

expresión   Requerida. Una expresión que devuelve un objeto Section.

Before   Variant opcional. Nombre o número de índice de la sección antes de la cual se moverá el objeto. No puede especificar Before si ha especificado After.

After   Variant opcional. Nombre o número de índice de la sección después de la cual se moverá el objeto. No puede especificar After si ha especificado Before.


Ejemplo del método Move

Este ejemplo mueve todos los libros de Microsoft Excel de Cuaderno1.obd a las últimas secciones del cuaderno.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

última = miCuaderno.Sections.Count

For Each sección In miCuaderno.Sections

    If sección.Type = "Excel.Sheet.8" Then

        sección.Move after:=última

    End If

Next


Propiedad Name

Objeto Binder: Devuelve el nombre de archivo del cuaderno, sin incluir la ruta. String de sólo lectura.

Objeto Section: Devuelve o configura el nombre de la sección, según se muestra en el icono del panel del Cuaderno. String de Lectura/Escritura.

Comentarios

Utilice la propiedad Path para devolver la ubicación y el nombre de archivo del cuaderno.


Ejemplo de la propiedad Name

Este ejemplo nombra la segunda sección de Cuaderno1.obd como "Presupuesto 95" y, a continuación, guarda los cambios en el cuaderno.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

If miCuaderno.Sections(2).Type = "Excel.Sheet.8" Then

    miCuaderno.Sections(2).Name = "Presupuesto 95"

    MsgBox "El contenido del cuaderno ha cambiado."

End If

miCuaderno.Save


Propiedad Object

Devuelve el objeto OLE asociado a la sección especificada. Es de sólo lectura.

Comentarios

Utilice esta propiedad para obtener acceso al contenido de la sección especificada (por ejemplo, el valor de la celda A1 en una hoja de cálculo de Microsoft Excel) y a todos los objetos, métodos y propiedades de la aplicación que creó la sección.


Ejemplo de la propiedad Object

Este ejemplo muestra el valor de la celda llamada "Total" en la hoja de cálculo uno de la sección "Ingresos 96" de Cuaderno1.obd.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

miCuaderno.Visible = True

total = miCuaderno.Sections("Ingresos 96").Object.Range("Total")

MsgBox "El total para 1996 es " & total


Propiedad Parent

Devuelve el objeto maestro del objeto especificado. Es de sólo lectura.


Ejemplo de la propiedad Parent

Este ejemplo agrega una nueva sección frente a Cuaderno1.obd y configura el nombre.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

Set nuevaSección = miCuaderno.Sections.Add(Type:="Word.Document", _

    Before:=1)

nuevaSección.Name = "Entrar a " & nuevaSección.Parent.Name


Propiedad Path

Devuelve la ruta y nombre de archivo completos del cuaderno especificado. String de sólo lectura.


Ejemplo de la propiedad Path

Este ejemplo solicita al usuario el nombre del cuaderno que se va a abrir y, a continuación, confirma la selección mostrando la ruta del cuaderno especificado.

miCuaderno = InputBox("Escriba el nombre del cuaderno que desee abrir")

Set miCuaderno = GetObject(miCuaderno, "OfficeBinder.Binder")

MsgBox "El cuaderno especificado está ubicado en " _

    & miCuaderno.Path


Método PrintOut

Imprime todas las secciones, un subconjunto o una única sección del cuaderno.

Sintaxis 1

expresión.PrintOut(What, Numbering, FirstPage, Sections, FileName, PrinterName, DriverName, NoPrinting)

Sintaxis 2

expresión.PrintOut

expresión   Requerida. Una expresión que devuelve un objeto Binder (Sintaxis 1) o un objeto Section (Sintaxis 2).

What   Variant requerida. Sección o secciones que se van a imprimir. Puede ser una de las siguientes constantes BindPrintWhat: bindPrintActiveSection, bindPrintVisibleSections, bindPrintSelectedSections, o bindPrintSectionSubset.

Numbering   Variant opcional. Esquema de numeración. Puede ser una de las siguientes constantes BindPrintNumbering: bindConsecutivePages o bindRestartEachSection. El valor predeterminado es bindConsecutivepages.

FirstPage   Variant opcional. Número de la primera página. Si se omite este argumento, la numeración comienza en 1.

Sections   Variant opcional. Si What es bindPrintSectionSubset, este argumento es una matriz unidimensional de los índices de las secciones que se imprimirá. Puede especificar el número de índice para imprimir una sección o una matriz unidimensional de índices para imprimir múltiples secciones.

FileName   Variant opcional. Nombre del archivo al que se redirigirá la impresión.

PrinterName   Variant opcional. Nombre de la impresora que se utilizará. Si este argumento se omite, se usará la impresora predeterminada.

DriverName   Variant opcional. Nombre del controlador de impresión que se utilizará. Si este argumento se omite, se usará el controlador predeterminado.

NoPrinting   Variant opcional. True para establecer PrinterName y DriverName pero sin imprimir nada. False (u omitido) para imprimir la sección o secciones específicas.

Comentarios

Puede imprimir una sección individual utilizando la Sintaxis 1 y especificando el número de la sección en el argumento Sections, o utilizando los métodos de impresión que cada tipo de sección facilite en su modelo de objeto (se accede a través de la propiedad Object).


Ejemplo del método PrintOut

Este ejemplo imprime todas las secciones visibles de Cuaderno1.obd. El número de la primera página es 10.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

miCuaderno.PrintOut what:=bindPrintVisibleSections, _

numbering:=bindConsecutivePages, firstPage:=10

Set miCuaderno = Nothing

Este ejemplo imprime las secciones primera y segunda y la sección denominada "Informe de Gastos" de Cuaderno4.obd.

Set miCuaderno = GetObject("Cuaderno4.obd", "OfficeBinder.Binder")

miCuaderno.PrintOut what:=bindPrintSectionSubset, _

sections:=Array(1, 2, "Informe de Gastos")

Set miCuaderno = Nothing


Método Save

Guarda los cambios de cuaderno especificado. Utilice este método sólo para cuadernos que hayan sido previamente guardados.

Sintaxis

expresión.Save

expresión   Requerida. Una expresión que devuelve un objeto Binder.

Comentarios

Si utiliza el método Save para guardar un cuaderno nuevo, se producirá un error. La primera vez que guarde un nuevo cuaderno, utilice el método SaveAs.


Ejemplo del método Save

Este ejemplo nombra la segunda sección de Cuaderno1.obd como "Presupuesto 95" y, a continuación, guarda los cambios en el cuaderno.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

If miCuaderno.Sections(2).Type = "Excel.Sheet.8" Then

    miCuaderno.Sections(2).Name = "Presupuesto 95"

    MsgBox "El contenido del cuaderno ha cambiado."

End If

miCuaderno.Save


Método SaveAs

Guarda los cambios del cuaderno o sección especificados en un archivo diferente. Utilice este método sólo para cuadernos visibles o para cuadernos nuevos que no hayan sido aún guardados. Devuelve True si el cuaderno se guarda o False si se produce un error y el cuaderno no puede guardarse.

Sintaxis 1

expresión.SaveAs(FileName, SaveOption)

Sintaxis 2

expresión.SaveAs(FileName)

expresión   Requerida. Una expresión que devuelve un objeto Binder (Sintaxis 1) o un objeto Section (Sintaxis 2).

FileName   Requerido para Section, opcional para Binder. Cadena que indica el nombre del archivo que se va a guardar. Puede incluir una ruta completa; si no lo hace, el archivo se guardará en la carpeta actual.

SaveOption   Variant opcional. Especifica la manera en que se guarda el cuaderno. Puede ser una de las siguientes constantes BindSaveOption:

Constante	Descripción
bindFailIfFileExists	Si FileName existe, se produce un error (FileName debe especificarse). Esta constante es el valor predeterminado.
bindOverwriteExisting	Si FileName existe, SaveAs lo sobrescribe (FileName debe especificarse).
bindDisplayDialog	Muestra el cuadro de diálogo Save As (FileName es opcional). Si el usuario cierra el cuadro de diálogo Save As sin guardar, SaveAs devuelve False.
Comentarios

El método SaveAs guarda las secciones como archivos independientes sin eliminar las secciones correspondientes del cuaderno. Si desea eliminar una sección del cuaderno, utilice el método Delete.


Ejemplo del método SaveAs

Este ejemplo determina si la sección activa de Cuaderno1.obd es del tipo Excel.Sheet.8. Si ese así, el ejemplo lo guarda como Libro1.xls.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

If miCuaderno.Sections(1).Type = "Excel.Sheet.8" Then

miCuaderno.Sections(1).SaveAs "Libro1.xls"

End If

Set miCuaderno = Nothing

Este ejemplo crea un nuevo cuaderno, lo muestra y, a continuación, solicita al usuario que lo guarde como Cuaderno1.obd.

Set nuevoCuaderno = CreateObject("OfficeBinder.Binder")

nuevoCuaderno.Visible = True

nuevoCuaderno.SaveAs fileName:="Cuaderno1.obd", _

saveOption:=bindDisplayDialog


Propiedad Sections

Devuelve un conjunto Sections que representa todas las secciones del cuaderno especificado. Es de sólo lectura.

Para obtener información acerca de cómo se devuelve un único miembro del conjunto, consulte Devolver un objeto de un conjunto.


Ejemplo de la propiedad Sections

Este ejemplo muestra el número de secciones de Microsoft Excel en Cuaderno1.obd.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

wk = 0

For Each s In miCuaderno.Sections

If s.Type = "Excel.Sheet.8" Then

wk = wk + 1

End If

Next

MsgBox "Hay " & wk & " secciones de Microsoft Excel en este cuaderno."

Set miCuaderno = Nothing

Este ejemplo muestra el nombre de la tercera sección de Cuaderno1.obd.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

MsgBox miCuaderno.Sections(3).Name

Set miCuaderno = Nothing


Propiedad SelectedSectionNames

Devuelve o configura la matriz que contiene los nombres de las secciones seleccionadas. Variant de Lectura/Escritura.

Comentarios

Al establecer la propiedad SelectedSectionNames la primera sección nombrada de la matriz se convierte en la sección activa. Si la matriz contiene el nombre de una sección que no existe, se produce un error.


Ejemplo de la propiedad SelectedSectionNames

Este ejemplo muestra el nombre de las secciones seleccionadas de Cuaderno1.obd.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno

mimatriz = .SelectedSectionNames

MsgBox UBound(mimatriz) & " sección está seleccionada."

For x = 1 To UBound(mimatriz)

    MsgBox "El nombre de la sección es " & mimatriz(x)

Next

End With


Propiedad Type

Devuelve una cadena que contiene el nombre largo OLE de la clase del objeto Section. String de sólo lectura.

Comentarios

Los nombres largos OLE de clase se especifican como appName.objectType.versionNumber (por ejemplo, "Word.Document.8"). Para obtener más información acerca de los tipos de secciones de cuaderno, consulte el método Add.


Ejemplo de la propiedad Type

Este ejemplo mueve todos los libros de Microsoft Excel de Cuaderno1.obd a las últimas secciones del cuaderno.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

última = miCuaderno.Sections.Count

For Each sección In miCuaderno.Sections

    If sección.Type = "Excel.Sheet.8" Then

        sección.Move after:=última

    End If

Next


Propiedad Visible

True si el cuaderno o sección especificados es visible. Boolean de Lectura/Escritura.

Comentarios

Cuando se crea un objeto Binder mediante la función CreateObject, o se abre mediante la función GetObject, la propiedad Visible es False. Para hacer que el cuaderno sea visible, configure la propiedad Visible como True.

Las secciones ocultas se incluyen en el recuento del conjunto Sections.


Ejemplo de la propiedad Visible

Este ejemplo abre Cuaderno1.obd y lo hace visible.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

miCuaderno.Visible = True


Método Open

Abre un cuaderno existente o un nuevo cuaderno basado en una plantilla de cuaderno existente.

Nota   El mejor método para abrir un cuaderno existente es mediante la función GetObject y, a continuación, utilizar el método Visible si desea mostrar el cuaderno al usuario. Si utiliza el método Open en lugar de la función GetObject, utilice el método Open inmediatamente después de utilizar CreateObject o de lo contrario se producirá un error.

Sintaxis

expresión.Open(FileName, OpenAsTemplate)

expresión   Requerida. Una expresión que devuelve un objeto Binder.

FileName   String requerida. Nombre del archivo que se va a abrir.

OpenAsTemplate   Variant opcional. True para abrir el archivo como un nuevo cuaderno basado en la plantilla de cuaderno especificada. False (u omitido) para abrir el archivo como un archivo de cuaderno.


Ejemplo del método Open

Este ejemplo abre Cuaderno2.obd. El ejemplo agrega un nuevo documento de Word al cuaderno y, a continuación, lo hace visible.

Set miCuaderno = CreateObject("OfficeBinder.Binder")

With miCuaderno

    .Open "Cuaderno2.obd"

    .Sections.Add Type:="Word.Document"

    .Visible = True

End With


Método Update

Actualiza la sección especificada, pero no guarda los cambios realizados en el cuaderno. Utilice el método Save para guardar los cambios realizados en el cuaderno.

Sintaxis

expresión.Update

expresión   Requerida. Una expresión que devuelve un objeto Section.

Comentarios

El método Update es útil si necesita actualizar varias secciones antes de guardar el cuaderno.


Ejemplo del método Update

Este ejemplo agrega una hoja de cálculo de Microsoft Excel a un cuaderno existente, inserta un valor en la hoja de cálculo y actualiza la nueva sección. Sin el método Update el cambio se perderá al establecer el nuevo objeto Section como Nothing. (Utilice el método Save para guardar permanentemente los cambios realizados al cuaderno.)

Set nuevoCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

Set nuevaSección = nuevoCuaderno.Sections.Add(Type:="Excel.Sheet")

With nuevaSección

    .Object.Worksheets(1).Range("a1").Value = 3.14159

    .Update

End With

Set nuevaSección = Nothing


Códigos de formato para encabezados y pies de página

Los códigos de formato especial que se muestran en la siguiente tabla pueden utilizarse con las propiedades de encabezado y pie de página (propiedad LeftHeader, propiedad CenterHeader, propiedad RightHeader, propiedad LeftFooter, propiedad CenterFooter y propiedad RightFooter).

Código de formato	Descripción
&L	Alinea a la izquierda los caracteres que le siguen.
&C	Centra los caracteres que le siguen.
&R	Alinea a la derecha los caracteres que le siguen.
&E	Activa o desactiva la impresión del doble subrayado.
&X	Activa o desactiva la impresión de superíndices.
&Y	Activa o desactiva la impresión de subíndices.
&B	Activa o desactiva la impresión de negritas.
&I	Activa o desactiva la impresión de cursiva.
&U	Activa o desactiva la impresión del subrayado.
&S	Activa o desactiva la impresión del tachado.
&O	Imprime el número de sección.
&H	Imprime el número total de secciones.
&D	Imprime la fecha actual.
&T	Imprime la hora actual.
&F	Imprime el nombre del documento.
&A	Imprime el nombre de la sección.
&P	Imprime el número de página.
&P+número	Imprime el número de página más el número.
&P-número	Imprime el número de página menos el número.
&&	Imprime un solo símbolo de "y" comercial.
& "fuente"	Imprime los caracteres que siguen en la fuente especificada. Asegúrese de incluir comillas dobles.
&nn	Imprime los caracteres que siguen en el tamaño de fuente especificado. Use un número de dos cifras para especificar un tamaño en puntos.
&N	Imprime el número total de páginas del documento.
&K	Imprime el nombre del usuario como una cadena de texto estático.
&M	Imprime el nombre de la organización como una cadena de texto estático.


Propiedad CenterFooter

Devuelve o configura la parte central del pie de página en las secciones que admiten encabezados o pies de página (o ambos) y que están incluidas en el cuaderno en el momento de configurar el pie de página. String de Lectura/Escritura.

Comentarios

Puede utilizar los códigos de formato especiales en el texto del pie de página.


Ejemplo de la propiedad CenterFooter

Este ejemplo imprime el número de página, en negrita y cursiva, en el centro de todas las páginas de cada sección de Cuaderno1.obd que admiten encabezados o pies de página (o ambos).

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno

For Each s In .Sections

    If s.SupportsBinderHeaderFooter Then

        .PageSetup.CenterFooter = "&B &I &P &B"

        s.HasBinderHeaderFooter = True

    End If

Next

.Close SaveChanges:=True

End With


Propiedad CenterHeader

Devuelve o configura la parte central del encabezado en las secciones que admiten encabezados o pies de página (o ambos) y que están incluidas en el cuaderno en el momento de configurar el encabezado. String de Lectura/Escritura.

Comentarios

Puede utilizar los códigos de formato especiales en el texto del encabezado.


Ejemplo de la propiedad CenterHeader

Este ejemplo imprime la fecha y hora, en negrita, en el centro de todas las páginas de cada sección de Cuaderno1.obd que admiten encabezados o pies de página (o ambos).

Set miCuaderno = GetObject("c:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno

For Each s In .Sections

    If s.SupportsBinderHeaderFooter Then

        .PageSetup.CenterHeader = "&B &D &T &B"

        s.HasBinderHeaderFooter = True

    End If

Next

.Close SaveChanges:=True

End With


Propiedad FirstPage

Devuelve o establece el número de la primera página de una sección que admita encabezados o pies de página (o ambos). Long de Lectura/Escritura.

Comentarios

Al crear un cuaderno por primera vez, el valor de esta propiedad es 1. Utilice esta propiedad si desea establecer un número en la primera página distinto de 1.


Ejemplo de la propiedad FirstPage

Este ejemplo imprime la primera sección de Cuaderno1.obd y comienza la numeración en 100. El número de página se imprimirá como un pie de página alineado a la derecha en la primera sección, si admite encabezados y pies de página (o ambos).

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno

If .Sections(1).SupportsBinderHeaderFooter Then

    With .PageSetup

        .FirstPage = 100

        .RightFooter = "&P"

        .PrintWhat = bindPageSetupSelectedSections

     End With

End If

.Close SaveChanges:=True

End With


Propiedad LeftFooter

Devuelve o configura la parte alineada a la izquierda del pie de página en las secciones que admiten encabezados o pies de página (o ambos) y que están incluidas en el cuaderno en el momento de configurar el pie de página. String de Lectura/Escritura.

Comentarios

Puede utilizar los códigos de formato especiales en el texto del pie de página.


Ejemplo de la propiedad LeftFooter

Este ejemplo imprime el número de página, en negrita y cursiva, en la esquina inferior izquierda de todas las páginas de cada sección de Cuaderno1.obd que admiten encabezados o pies de página (o ambos).

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno

For Each s In .Sections

    If s.SupportsBinderHeaderFooter Then

        s.PageSetup.LeftFooter = "&B &I &P &B"

        s.HasBinderHeaderFooter = True

    End If

Next

.Close SaveChanges:=True

End With


Propiedad LeftHeader

Devuelve o configura la parte alineada a la izquierda del encabezado en las secciones que admiten encabezados o pies de página (o ambos) y que están incluidas en el cuaderno en el momento de configurar el encabezado. String de Lectura/Escritura.

Comentarios

Puede utilizar los códigos de formato especiales en el texto del encabezado.


Ejemplo de la propiedad LeftHeader

Este ejemplo imprime la fecha y hora, en negrita, en la esquina superior izquierda de todas las páginas de cada sección de Cuaderno1.obd que admiten encabezados o pies de página (o ambos).

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno

For Each s In .Sections

    If s.SupportsBinderHeaderFooter Then

        .PageSetup.LeftHeader = "&B &D &T &B"

        s.HasBinderHeaderFooter = True

    End If

Next

.Close SaveChanges:=True

End With


Propiedad Numbering

Devuelve o establece el tipo de numeración que contendrá las secciones del cuaderno especificado. Puede ser una de las siguientes constantes BindPrintNumbering: bindConsecutivePages o bindRestartEachSection. Variant de Lectura/Escritura.


Ejemplo de la propiedad Numbering

Este ejemplo ubica el número de página en la esquina inferior izquierda de cada página de Cuaderno1.obd y reinicia la numeración al comienzo de cada sección del cuaderno.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno.PageSetup

    .LeftFooter = "&P"

    .Numbering = bindRestartEachSection

End With


Propiedad PrintWhat

Devuelve o establece las secciones del cuaderno especificado que se imprimirán. Puede ser una de las siguientes constantes BindPageSetupPrintWhat: bindPageSetupSelectedSections o bindPageSetupVisibleSections. Variant de Lectura/Escritura.


Ejemplo de la propiedad PrintWhat

Este ejemplo ubica la fecha y la hora en la esquina superior izquierda de cada página de Cuaderno1.obd y establece todas las secciones visibles del cuaderno que admiten encabezados o pies de página (o ambos) que se imprimirán.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno

For Each s In .Sections

    If s.SupportsBinderHeaderFooter Then

        .PageSetup.LeftHeader = "&D &T"

        .PageSetup.PrintWhat = bindPageSetupVisibleSections

        s.HasBinderHeaderFooter = True

    End If

Next

.Close SaveChanges:=True

End With


Propiedad RightFooter

Devuelve o configura la parte alineada a la derecha del pie de página en las secciones que admiten encabezados o pies de página (o ambos) y que están incluidas en el cuaderno en el momento de configurar el pie de página. String de Lectura/Escritura.

Comentarios

Puede utilizar los códigos de formato especiales en el texto del pie de página.


Ejemplo de la propiedad RightFooter

Este ejemplo imprime el número de página, en negrita y cursiva, en la esquina inferior derecha de todas las páginas de cada sección de Cuaderno1.obd que admiten encabezados o pies de página (o ambos).

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno

For Each s In .Sections

    If s.SupportsBinderHeaderFooter Then

        .PageSetup.RightFooter = "&B &I &P &B"

        s.HasBinderHeaderFooter = True

    End If

Next

.Close SaveChanges:=True

End With


Propiedad RightHeader

Devuelve o configura la parte alineada a la derecha del encabezado en las secciones del cuaderno especificado que admiten encabezados o pies de página (o ambos) y que están incluidas en el cuaderno en el momento de configurar el encabezado. String de Lectura/Escritura.

Comentarios

Puede utilizar los códigos de formato especiales en el texto del encabezado.


Ejemplo de la propiedad RightHeader

Este ejemplo imprime la fecha y hora, en negrita, en la esquina superior derecha de todas las páginas de cada sección de Cuaderno1.obd que admiten encabezados o pies de página (o ambos).

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno

For Each s In .Sections

    If s.SupportsBinderHeaderFooter Then

        .PageSetup.LeftHeader = "&B &D &T &B"

        s.HasBinderHeaderFooter = True

    End If

Next

.Close SaveChanges:=True

End With


Método Close

Cierra el cuaderno especificado.

Sintaxis

expresión.Close(SaveChanges, FileName)

expresión   Requerida. Una expresión que devuelve un objeto Binder.

SaveChanges   Variant opcional. True para guardar los cambios del cuaderno. False para guardar el cuaderno sin cambios. Si se omite este argumento y se han realizado cambios en el cuaderno, se muestra un cuadro de diálogo preguntando al usuario si desea guardar los cambios. Si no hay cambios, se ignorará este argumento.

FileName   Variant opcional. Nombre que desee asignar al cuaderno para guardarlo, si no ha sido guardado anteriormente. Si se omite este argumento y el cuaderno no se ha guardado al menos una vez, se mostrará el cuadro de diálogo Guardar como. Si el cuaderno ya ha sido guardado, se ignorará este argumento.


Ejemplo del método Close

Este ejemplo cierra el cuaderno representado por nuevoCuaderno y lo guarda como NuevoCuaderno2.obd.

nuevoCuaderno.Close _

SaveChanges:=True,FileName:="NuevoCuaderno2.obd"


Propiedad DefaultFilePath

Devuelve o establece la ruta de acceso predeterminada utilizada por Cuaderno de Microsoft Office para abrir o guardar archivos. String de Lectura/Escritura.

Comentarios

La ruta predeterminada después de la instalación de Microsoft Office es C:\Mis documentos.


Ejemplo de la propiedad DefaultFilePath

Este ejemplo muestra la ruta de acceso de archivos predeterminada actual.

MsgBox "La ruta de archivos predeterminada actual es " & _

nuevoCuaderno.DefaultFilePath


Propiedad DisplayAlerts

True si Cuaderno de Microsoft Office muestra determinadas alertas y mensajes cuando el cuaderno especificado está activo. Boolean de Lectura/Escritura.


Ejemplo de la propiedad DisplayAlerts

Este ejemplo cierra el cuaderno representado por nuevoCuaderno sin pedir al usuario que guarde los cambios. No se guardan los cambios realizados en el cuaderno.

nuevoCuaderno.DisplayAlerts = False

nuevoCuaderno.Close


Método ExitOpenMode

Cierra la aplicación host y vuelve a Cuaderno de Microsoft Office.

Sintaxis

expresión.ExitOpenMode

expresión   Requerida. Una expresión que devuelve un objeto Binder.


Ejemplo del método ExitOpenMode

Este ejemplo agrega un nuevo libro de Microsoft Excel al cuaderno y abre la nueva sección en la aplicación host (Microsoft Excel).  Agrega el número 45 a un rango en una hoja de cálculo y, a continuación, cierra la aplicación host y guarda el nuevo archivo de cuaderno.

Set nuevoCuaderno = GetObject("C:\Cuaderno2.obd", _

"Office.Binder")

nuevoCuaderno.ViewOpenMode

Set nuevaSección = nuevoCuaderno.Sections.Add(Type:="Excel.Sheet")

With nuevaSección

    .Object.Worksheets(1).Range("a1").Value = 45

End With

nuevoCuaderno.ExitOpenMode

nuevoCuaderno.Close _

savechanges:=True, FileName:="cambiado.obd"


Propiedad DisplayLeftPaneAndButton

True si están visibles el panel izquierdo (también conocido como panel del Cuaderno) del cuaderno especificado y el botón que permite al usuario mostrar este panel. Boolean de Lectura/Escritura.


Ejemplo de la propiedad DisplayLeftPaneAndButton

Este ejemplo muestra el cuaderno representado por nuevoCuaderno pero no muestra el panel del Cuaderno. El botón que permite al usuario mostrar este panel no está disponible.

nuevoCuaderno.DisplayLeftPaneAndButton = False

nuevoCuaderno.Visible = True


Propiedad PageSetup

Devuelve un objeto PageSetup que representa la descripción de la configuración de página. Es de sólo lectura.


Ejemplo de la propiedad PageSetup

Este ejemplo imprime el número de página, en negrita y cursiva, en el centro de cada página del cuaderno representado por miCuaderno.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

miCuaderno.PageSetup.CenterFooter = "&B &I &P &B"


Propiedad SinglePrintJob

True si todas las secciones del cuaderno se imprimen juntas, como una unidad. False si cada sección del cuaderno se imprime como un trabajo independiente. Boolean de Lectura/Escritura.


Ejemplo de la propiedad SinglePrintJob

Este ejemplo abre un archivo de cuaderno y lo imprime como un trabajo independiente.

Set nuevoCuaderno = GetObject("C:\Cuaderno2.obd", _

"Office.Binder")

With nuevoCuaderno

    .SinglePrintJob = True

    .PrintOut what:=bindPrintVisibleSections, _

    Numbering:=bindConsecutivePages

    .Close _

    SaveChanges:=True, FileName:="cambiado.obd"

End With


Método ViewOpenMode

Muestra la sección activa del cuaderno especificado en la aplicación host de la sección.

Sintaxis

expresión.ViewOpenMode

expresión   Requerida. Una expresión que devuelve un objeto Binder.

Comentarios

Si la aplicación host no está disponible o no está instalada, se producirá un error.


Ejemplo del método ViewOpenMode

Este ejemplo agrega un nuevo libro de Microsoft Excel al cuaderno y abre la nueva sección en la aplicación host (Microsoft Excel).  Agrega el número 45 a un rango en una hoja de cálculo y, a continuación, cierra la aplicación host y guarda el nuevo archivo de cuaderno.

Set nuevoCuaderno = GetObject("C:\Cuaderno2.obd", _

"Office.Binder")

nuevoCuaderno.ViewOpenMode

Set nuevaSección = nuevoCuaderno.Sections.Add(Type:="Excel.Sheet")

With nuevaSección

    .Object.Worksheets(1).Range("a1").Value = 45

End With

nuevoCuaderno.ExitOpenMode

nuevoCuaderno.Close _

savechanges:=True, FileName:="changed.obd"


Propiedad DisplayStatusBar

True si Cuaderno de Microsoft Office muestra una barra de estado en la parte inferior de la ventana de aplicación. Boolean de Lectura/Escritura.


Ejemplo de la propiedad DisplayStatusBar

En este ejemplo se abre Cuaderno2.obd, se muestra la barra de estado y se hace visible el cuaderno.

Set newb = GetObject("C:\Cuaderno2.obd", "Office.Binder")

newb.DisplayStatusBar = True

newb.Visible = True


Propiedad ActiveSection

Devuelve un objeto Section que representa la sección activa del cuaderno. Si el cuaderno no tiene ninguna sección visible, se produce un error. Es de sólo lectura.

Comentarios

Para convertir una sección en la sección activa, use el método Activate.


Ejemplo de la propiedad ActiveSection

En este ejemplo se abre Cuaderno2.obd, se activa la primera sección y se crea una copia de la sección activa, si la sección activa es un gráfico de Excel. A la nueva sección se le da el nombre "Copia de Sección 1".

Set NuevoCuaderno = GetObject("C:\Cuaderno2.obd", _

    "Office.Binder")

With NuevoCuaderno

    .Visible = True

    .Sections(1).Activate

    If .ActiveSection.Type = "Excel.Chart.8" Then

        .ActiveSection.Copy

        .ActiveSection.Name = "Copia de Sección 1"

    End If

End With


Propiedad HasBinderHeaderFooter

True si la sección del cuaderno especificada contiene un encabezado o pie de página que se puede imprimir. Boolean de Lectura/Escritura.


Ejemplo de la propiedad HasBinderHeaderFooter

En este ejemplo se imprime el número de página, en negrita y cursiva, en el centro de todas las páginas de cada sección de Cuaderno1.obd que admitan encabezados o pies de página, o ambos.

Set MiCuaderno = GetObject("C:\Cuaderno1.obd", _

    "OfficeBinder.Binder")

With MiCuaderno

For Each s In .Sections

    If s.SupportsBinderHeaderFooter Then

        .PageSetup.CenterFooter = "&B &I &P &B"

        s.HasBinderHeaderFooter = True

    End If

Next

.Close SaveChanges:=True

End With


Propiedad SupportsBinderHeaderFooter

True si la sección del cuaderno especificada admite encabezados o pies de página. Boolean de sólo lectura.


Ejemplo de la propiedad SupportsBinderHeaderFooter

En este ejemplo se imprime el número de página, en negrita y cursiva, en el centro de todas las páginas de cada sección de Cuaderno1.obd que admita encabezados o pies de página, o ambos.

Set MiCuaderno = GetObject("C:\Cuaderno1.obd", _

    "OfficeBinder.Binder")

With MiCuaderno

For Each s In .Sections

    If s.SupportsBinderHeaderFooter Then

        .PageSetup.CenterFooter = "&B &I &P &B"

        s.HasBinderHeaderFooter = True

    End If

Next

.Close SaveChanges:=True

End With


Objeto Section

Representa una sección (un documento específico) de un cuaderno. Por ejemplo, si un cuaderno contiene una hoja de cálculo de Microsoft Excel, dos documentos de Word y una presentación de PowerPoint, el cuaderno contiene cuatro secciones. El objeto Section es un miembro del conjunto Sections.

Uso del objeto Section

Utilice Sections(índice), donde índice es el número de la sección que desee devolver, para devolver un objeto Section. El número de índice representa el orden en que aparecen las secciones en el panel del Cuaderno. Sections(1) es el primer documento y Sections(Sections.Count) es el último documento.

Al activar una sección se abre el documento en el lugar, no cambia el número de índice del documento. Todas las secciones se incluyen en el número de índice, aunque estén ocultas. El siguiente ejemplo activa el primer documento del cuaderno representado por miCuaderno.

miCuaderno.Sections(1).Activate

Comentarios

La propiedad Name devuelve o establece el nombre de la sección especificada. El siguiente ejemplo muestra el nombre de la primera sección de Cuaderno1.obd.

Set miCuaderno = GetObject("Cuaderno1.obd", "OfficeBinder.Binder")

nombre = miCuaderno.Sections(1).Name

Set miCuaderno = Nothing

MsgBox nombre

Utilice el método SaveAs para guardar una copia de la sección especificada en un archivo diferente. El siguiente ejemplo guarda la sección uno de Cuaderno1.obd en un nuevo libro de Microsoft Excel.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

If miCuaderno.Sections(1).Type = "Excel.Sheet.8" Then

miCuaderno.Sections(1).SaveAs "MiLibro3.xls"

End If

El siguiente ejemplo activa la sección "Sumaventas" en Informe Anual.obd.

Set miCuaderno = GetObject("C:\informes\Informe Anual.obd", _

"OfficeBinder.Binder")

miCuaderno.Visible = True

miCuaderno.Sections("Sumaventas").Activate


Objeto del conjunto Sections

Conjunto de todos los objetos Section de un cuaderno, sean o no visibles.

Uso del conjunto Sections

Utilice la propiedad Sections para devolver el conjunto Sections. El siguiente ejemplo muestra el número de secciones de Cuaderno1.obd.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

MsgBox "hay " & miCuaderno.Sections.Count & _

    " secciones en este cuaderno"

Utilice el método Add para crear una nueva sección o agregar un archivo existente como una sección. El siguiente ejemplo agrega un libro de Microsoft Excel vacío a un cuaderno nuevo.

Set miCuaderno = CreateObject("OfficeBinder.Binder")

miCuaderno.Sections.Add Type:="Excel.Sheet"

El siguiente ejemplo abre un cuaderno existente y agrega el archivo de Word Ejemplos.doc como la última sección del cuaderno.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

miCuaderno.Sections.Add _

    FileName:="C:\Archivos de programa\Microsoft Office\Winword\Ejemplos.doc"

Utilice Sections(índice), donde índice es el número de la sección que desee devolver, para devolver un objeto Section. El siguiente ejemplo nombra la segunda sección de Cuaderno1.objd como "Presupuesto 95" y, a continuación, guarda los cambios.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

If miCuaderno.Sections(2).Type = "Excel.Sheet.8" Then

    miCuaderno.Sections(2).Name = "Presupuesto 95"

    MsgBox "El contenido del cuaderno ha cambiado."

End If

miCuaderno.Save


Objeto Binder

Representa un cuaderno de Microsoft Office. En Visual Basic un cuaderno se crea o se abre como un objeto de Automatización (anteriormente objeto de Automatización OLE).

Uso del objeto Binder

Utilice la función CreateObject para crear un nuevo cuaderno. El siguiente ejemplo crea un nuevo cuaderno, lo hace visible y, a continuación, lo guarda como Micuaderno.obd.

Set miCuaderno = CreateObject("OfficeBinder.Binder")

miCuaderno.Visible = True

miCuaderno.SaveAs Filename := "Micuaderno.obd"

Utilice la función GetObject para abrir un cuaderno existente. El siguiente ejemplo abre el cuaderno anteriormente creado y lo hace visible.

Set miCuaderno = GetObject("Micuaderno.obd", "OfficeBinder.Binder")

miCuaderno.Visible = True

Comentarios

Cuando se crea o se abre un cuaderno, de forma predeterminada está oculto. Establezca la propiedad Visible del cuaderno especificado en True para mostrar el cuaderno.


Objeto PageSetup

Representa la descripción de la configuración de página. El objeto PageSetup contiene todos los atributos de configuración de página (pie de página izquierdo, encabezado central, numeración, etc.) como propiedades.

Uso del objeto PageSetup

Utilice la propiedad PageSetup para devolver el objeto PageSetup. Este ejemplo imprime las secciones visibles del cuaderno e inicia la numeración en 100. Los números de página se imprimen como pies de página alineados a la derecha.

Set miCuaderno = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno.PageSetup

    .FirstPage = 100

    .RightFooter = "&P"

    .PrintWhat = bindPrintVisibleSections

End With

Comentarios

Para imprimir un encabezado o pie de página de una sección, ésta debe admitir encabezados o pies de página (o ambos) y debe contener un encabezado o pie de página imprimible. Utilice la propiedad SupportsBinderHeaderFooter para determinar si la sección admite encabezados o pies de página. Utilice HasBinderHeaderFooter para determinar si la sección contiene un encabezado o pie de página imprimible. El siguiente ejemplo establece el número de página, en negrita, en el centro de cada página de las secciones de Cuaderno1.obd que admiten encabezados o pies de página y, a continuación, imprime todas las secciones visibles del cuaderno.

Set miCuaderno = GetObject("c:\Cuaderno1.obd", "OfficeBinder.Binder")

With miCuaderno

For Each s In .Sections

    If s.SupportsBinderHeaderFooter Then

        .PageSetup.CenterFooter = "&B &P &B"

        s.HasBinderHeaderFooter = True

    End If

Next

miCuaderno.PrintOut What:=bindPrintVisibleSections

.Close SaveChanges:=True

End With


Propiedad BuiltinDocumentProperties

Devuelve un conjunto DocumentProperties que representa todas las propiedades de documento integradas del cuaderno especificado. Es de sólo lectura.

Comentarios

Utilice la propiedad CustomDocumentProperties para devolver el conjunto DocumentProperties que representa todas las propiedades de documento del cuaderno especificado.


Ejemplo de la propiedad BuiltinDocumentProperties

Este ejemplo muestra el nombre del autor de Cuaderno1.obd.

Set nb = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

MsgBox nb.BuiltinDocumentProperties("Autor").Value

Set nb = Nothing


Propiedad CustomDocumentProperties

Devuelve un conjunto DocumentProperties que representa todas las propiedades de documento personalizadas del cuaderno especificado. Es de sólo lectura.

Comentarios

Utilice la propiedad BuiltinDocumentProperties para devolver el conjunto DocumentProperties que representa todas las propiedades de documento integradas del cuaderno especificado.


Ejemplo de la propiedad CustomDocumentProperties

Este ejemplo agrega una propiedad de documento personalizada a Cuaderno1.obd y, a continuación, guarda el cuaderno.

Set nb = GetObject("C:\Cuaderno1.obd", "OfficeBinder.Binder")

nb.CustomDocumentProperties.Add Name:="completo", _

    LinkToContent:=False, Type:=offPropertyTypeBoolean, Value:=False

nb.Save

Set nb = Nothing


Objetos del Cuaderno de Microsoft Office


Identificadores programáticos OLE (Cuaderno de Microsoft Office)

Se usa un identificador programático, algunas veces denominado ProgID, para crear un objeto Automatización.

Para crear un objeto Automatización que representa un objeto Binder Cuaderno de Microsoft Office, use "OfficeBinder.Binder.8." Al usar "OfficeBinder.Binder" sin número de versión se crea un cuaderno en la última versión disponible de Cuaderno de Microsoft Office en el sistema donde la macro se esté ejecutando.


Devolver un objeto de un conjunto

La propiedad Item devuelve un solo objeto de un conjunto. En el siguiente ejemplo se establece la variable MiSección como un objeto Section que representa la primera sección de un cuaderno. La variable MiCuaderno se establece como un archivo de cuaderno existente.

Set MiSección = miCuaderno.Sections.Item(1)

La propiedad Item es la propiedad predeterminada del conjunto Sections, de este modo se puede escribir la misma instrucción de una forma mas concisa al omitir la palabra clave Item.

Set MiSección = miCuaderno.Sections.Item(1)


Tema de ayuda no disponible

No se puede mostrar el tema de ayuda porque no se ha encontrado o no se ha instalado la Ayuda de Visual Basic para aplicaciones.

Instalación de la Ayuda de Visual Basic para aplicaciones

1.	Ejecute el programa de instalación de Microsoft Office 97 y haga clic en Agregar o Quitar.

2.	Haga clic en Microsoft Excel, Microsoft PowerPoint o Microsoft Word y, a continuación, haga clic en Modificar opción.

3.	Haga clic en Ayuda y luego en Modificar opción.

4.	Asegúrese de que la casilla de verificación  Ayuda de Visual Basic esté activada.

5.	Continúe con la instalación.


Tema de ayuda no disponible

No se puede mostrar el tema de ayuda porque no se ha encontrado o no se ha instalado la ayuda de Visual Basic de Microsoft Office.

Instalación de la Ayuda de Visual Basic para aplicaciones

1.	Ejecute el programa de instalación de Microsoft Office 97 y haga clic en Agregar o Quitar.

2.	Haga clic en Microsoft Excel, Microsoft PowerPoint o Microsoft Word y, a continuación, haga clic en Modificar opción.

3.	Haga clic en Ayuda y luego en Modificar opción.

4.	Asegúrese de que la casilla de verificación  Ayuda de Visual Basic esté activada.

5.	Continúe con la instalación.